sfplist

sfplist — Prints a list of all presets of a SoundFont2 (SF2) sample file.

Description

Prints a list of all presets of a previously loaded SoundFont2 (SF2) sample file. These opcodes allow management the sample-structure of SF2 files. In order to understand the usage of these opcodes, the user must have some knowledge of the SF2 format, so a brief description of this format can be found in the SoundFont2 File Format Appendix.

Syntax

sfplist ifilhandle

Initialization

ifilhandle -- unique number generated by sfload opcode to be used as an identifier for a SF2 file. Several SF2 files can be loaded and activated at the same time.

Performance

sfplist prints a list of all presets of a previously loaded SF2 file to the console.

These opcodes only support the sample structure of SF2 files. The modulator structure of the SoundFont2 format is not supported in Csound. Any modulation or processing to the sample data is left to the Csound user, bypassing all restrictions forced by the SF2 standard.

Examples

Here is an example of the sfplist opcode. It uses the file sfplist.csd.

Example 789. Example of the sfplist opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac -+rtmidi=virtual -M0  ;;;realtime audio out, virtual midi in
;-iadc    ;;;uncomment -iadc if RT audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o sfplist.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

gisf	sfload	 "sf_GMbank.sf2"
	sfplist	 gisf					;list all presets
gir	sfpreset 125, 3, gisf, 0 			;preset = Car Pass

instr 1	; play from score and midi keyboard

	mididefault	60, p3
	midinoteonkey	p4, p5
inum	init	p4
ivel	init	p5
ivel	init	ivel/127				;make velocity dependent
kamp	linsegr	1, 1, 1, .1, 0
kamp	= kamp/6000					;scale amplitude
kfreq	init	1					;do not change freq from sf
a1,a2	sfplay3	ivel, inum, kamp, kfreq, gir
	outs	a1, a2
	
endin
	
</CsInstruments>
<CsScore>
f0  60				; stay active for 1 minute

i1 0 1 60 127
i1 + 1 62 <
i1 + 1 65 <
i1 + 1 69 10

e
</CsScore>
</CsoundSynthesizer>


Its output should include lines like this:

Preset list of "sf_GMbank.sf2"
  0) Piano 1             	prog:0   bank:0
  1) Piano 2             	prog:1   bank:0
  2) Piano 3             	prog:2   bank:0
  3) Honky Tonk          	prog:3   bank:0
  4) E.Piano 1           	prog:4   bank:0
  5) E.Piano 2           	prog:5   bank:0
  6) Harpsichord         	prog:6   bank:0
  ........
  146) Car-Pass            	prog:125 bank:3
  ........
      

See Also

sfilist, sfinstr, sfinstrm, sfload, sfpassign, sfplay, sfplaym, sfpreset

Credits

Author: Gabriel Maldonado
Italy
May 2000

New in Csound Version 4.07