Description

Sends an arate signal out from an instrument to a named port.

Syntax

outleta Sname, asignal

Initialization

Sname -- String name of the outlet port. The name of the outlet is implicitly qualified by the instrument name or number, so it is valid to use the same outlet name in more than one instrument (but not to use the same outlet name twice in one instrument).

Performance

asignal -- audio output signal

During performance, the audio output signal is sent to each instance of an instrument containing an inlet port to which this outlet has been connected using the connect opcode. The signals of all the outlets connected to an inlet are summed in the inlet.

Examples

Here is an example of the outleta opcode. It uses the file outleta.csd.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac    ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o outleta.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1 

connect	 "1", "Outl", "reverby", "InL" 
connect	 "1", "Outr", "reverby", "InR" 

alwayson "reverby", 1

instr 1

aIn diskin2 "fox.wav", 1 
    outleta "Outl", aIn 
    outleta "Outr", aIn 

endin 

instr reverby

aInL   inleta "InL" 
aInR   inleta "InR" 

al, ar reverbsc	aInL, aInR, 0.7, 21000 
ifxlev = 0.5 
al     = (aInL*ifxlev)+(al*(1-ifxlev)) 
ar     = (aInR*ifxlev)+(ar*(1-ifxlev)) 
       outs al, ar 
                                
endin 
</CsInstruments>
<CsScore>

i 1 0 3 
e4
</CsScore>
</CsoundSynthesizer>

See Also

outletk outletkid outletf inleta inletk inletkid inletf connect alwayson ftgenonce

More information on this opcode: http://www.csoundjournal.com/issue13/signalFlowGraphOpcodes.html , written by Michael Gogins

Credits

By: Michael Gogins 2009