vdelayxs

vdelayxs — A stereo variable delay opcode with high quality interpolation.

Description

A stereo variable delay opcode with high quality interpolation.

Syntax

aout1, aout2 vdelayxs ain1, ain2, adl, imd, iws [, ist]

Initialization

imd -- max. delay time (seconds)

iws -- interpolation window size (see below)

ist (optional) -- skip initialization if not zero

Performance

aout1, aout2 -- output audio signals

ain1, ain2 -- input audio signals

adl -- delay time in seconds

This opcode uses high quality (and slow) interpolation, that is much more accurate than the currently available linear and cubic interpolation. The iws parameter sets the number of input samples used for calculating one output sample (allowed values are any integer multiply of 4 in the range 4 - 1024); higher values mean better quality and slower speed.

The multichannel opcodes (eg. vdelayxq) allow delaying 2 or 4 variables at once (stereo or quad signals); this is much more efficient than using separate opcodes for each channel.

[Note] Notes

  • Delay time is measured in seconds (unlike in vdelay and vdelay3), and must be a-rate.

  • The minimum allowed delay is iws/2 samples.

  • Using the same variables as input and output is allowed in these opcodes.

  • In vdelayxw*, changing the delay time has some effects on output volume:

    a = 1 / (1 + dt)

    where a is the output gain, and dt is the change of delay time per seconds.

  • These opcodes are best used in the double-precision version of Csound.

Examples

Here is an example of the use of the vdelayxs opcode. It uses the file vdelayxs.csd.

Example 961. Example of the vdelayxs opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac  ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o vdelayxs.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1 

ims  =	.5						;maximum delay time in seconds
iws  =	1024						;window size
adl  =	.5						;delay time
asig1, asig2 diskin2 "kickroll.wav", 1, 0, 1		;loop stereo file kickroll.wav
a2   poscil .25, .1, 1					;make an LFO, 1 cycle per 2 seconds
adl  = a2 + ims/2      					;offset the LFO so that it is positive
aoutL, aoutR vdelayxs asig1, asig2, adl, ims, iws	;use the LFO to control delay time
     outs aoutL, aoutR

endin
</CsInstruments>
<CsScore>
f1 0 8192 10 1

i 1 0 10

e
</CsScore>
</CsoundSynthesizer>


See Also

vdelayx, vdelayxq, vdelayxw, vdelayxwq, vdelayxws