tambourine

tambourine — Semi-physical model of a tambourine sound.

Description

tambourine is a semi-physical model of a tambourine sound. It is one of the PhISEM percussion opcodes. PhISEM (Physically Informed Stochastic Event Modeling) is an algorithmic approach for simulating collisions of multiple independent sound producing objects.

Syntax

ares tambourine kamp, idettack [, inum] [, idamp] [, imaxshake] [, ifreq] \
      [, ifreq1] [, ifreq2]

Initialization

idettack -- period of time over which all sound is stopped

inum (optional) -- The number of beads, teeth, bells, timbrels, etc. If zero, the default value is 32.

idamp (optional) -- the damping factor, as part of this equation:

damping_amount = 0.9985 + (idamp * 0.002)

The default damping_amount is 0.9985 which means that the default value of idamp is 0. The maximum damping_amount is 1.0 (no damping). This means the maximum value for idamp is 0.75.

The recommended range for idamp is usually below 75% of the maximum value.

imaxshake (optional, default=0) -- amount of energy to add back into the system. The value should be in range 0 to 1.

ifreq (optional) -- the main resonant frequency. The default value is 2300.

ifreq1 (optional) -- the first resonant frequency. The default value is 5600.

ifreq2 (optional) -- the second resonant frequency. The default value is 8100.

Performance

kamp -- Amplitude of output. Note: As these instruments are stochastic, this is only an approximation.

Examples

Here is an example of the tambourine opcode. It uses the file tambourine.csd.

Example 890. Example of the tambourine opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac      ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o tambourine.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1

idamp = p4
asig  tambourine .8, 0.01, 30, idamp
      outs asig, asig

endin
</CsInstruments>
<CsScore>

i 1 0 .2 0
i 1 + .2 >
i 1 + 1 .7
e
</CsScore>
</CsoundSynthesizer>


See Also

bamboo, dripwater, guiro, sleighbells

Credits

Author: Perry Cook, part of the PhISEM (Physically Informed Stochastic Event Modeling)
Adapted by John ffitch
University of Bath, Codemist Ltd.
Bath, UK

New in Csound version 4.07

Added notes by Rasmus Ekman on May 2002.