jitter

jitter — Generates a segmented line whose segments are randomly generated.

Description

Generates a segmented line whose segments are randomly generated.

Syntax

kout jitter kamp, kcpsMin, kcpsMax

Performance

kamp -- Amplitude of jitter deviation

kcpsMin -- Minimum speed of random frequency variations (expressed in cps)

kcpsMax -- Maximum speed of random frequency variations (expressed in cps)

jitter generates a segmented line whose segments are randomly generated inside the +kamp and -kamp interval. Duration of each segment is a random value generated according to kcpsmin and kcpsmax values.

jitter can be used to make more natural and analog-sounding some static, dull sound. For best results, it is suggested to keep its amplitude moderate.

Examples

Here is an example of the jitter opcode. It uses the file jitter.csd.

Example 398. Example of the jitter opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o jitter.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1

kamp    init p4
kcpsmin init 4
kcpsmax init 8

kj2  jitter kamp, kcpsmin, kcpsmax
aout pluck 1, 200+kj2, 1000, 0, 1
aout dcblock aout	;remove DC
     outs aout, aout

endin
</CsInstruments>
<CsScore>

i 1 0 15 2	;a bit jitter
i 1 8 15 10	;some more
i 1 16 15 20	;lots more
e
</CsScore>
</CsoundSynthesizer>


See Also

jitter2, vibr, vibrato

Credits

Author: Gabriel Maldonado

New in Version 4.15