fractalnoise

fractalnoise — A fractal noise generator.

Description

A fractal noise generator implemented as a white noise filtered by a cascade of 15 first-order filters.

Syntax

ares fractalnoise kamp, kbeta

Performance

kamp -- amplitude.

kbeta -- spectral parameter related to the fractal dimension

  • 0 - white

  • 1 - pink

  • 2 - brown

Examples

Here is an example of the fractalnoise opcode. It uses the file fractalnoise.csd.

Example 325. Example of the fractalnoise opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o oscil.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1

kbeta linseg 0, p3/4, 2, p3/4, 0, p3*0.1, 2, p3*0.15, 0
seed  20120124
aout  fractalnoise 0.05, kbeta 
outs  aout, aout

endin
</CsInstruments>
<CsScore>
i1 0 10
e
</CsScore>
</CsoundSynthesizer>


References

  1. R. Saletti. A comparison between two methods to generate 1/(f^gamma) noise. In Proc. IEEE, volume 74, pp. 1595-1596, November 1986.

  2. G. Corsini and R. Saletti. A 1/(f^gamma) power spectrum noise sequence generator. IEEE Trans. on Instrumentation and Measurement, 37(4):615-619, December 1988.

  3. The Sounding Object, edited by Davide Rocchesso and Federico Fontana, Edizioni di Mondo Estremo. Chapter 8 by Federico Avanzini, pp. 154-157.

Credits

Author: Tito Latini
January 2012

New in Csound version 5.16