else

else — Executes a block of code when an "if...then" condition is false.

Description

Executes a block of code when an "if...then" condition is false.

Syntax

          
            else
          
        

Performance

else is used inside of a block of code between the "if...then" and endif opcodes. It defines which statements are executed when a "if...then" condition is false. Only one else statement may occur and it must be the last conditional statement before the endif opcode.

Examples

Here is an example of the else opcode. It uses the file else.csd.

Example 208. Example of the else opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o else.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs = 1

instr 1

ipch = cpspch(p4)
ienv = p5


if (ienv == 0) then 	
	kenv adsr 0.01, 0.95, .7, .5
else
	kenv linseg 0, p3 * .5, 1, p3 * .5, 0
endif

aout vco2    .8, ipch, 10
aout moogvcf aout, ipch + (kenv * 6 * ipch) , .5

aout = aout * kenv
    outs aout, aout

endin
</CsInstruments>
<CsScore>

i 1 0 2 8.00 0
i 1 3 2 8.00 1

e
</CsScore>
</CsoundSynthesizer>


See Also

elseif, endif, goto, if, igoto, kgoto, tigoto, timout

More information on this opcode: http://www.csounds.com/journal/2006spring/controlFlow.html , written by Steven Yi

Credits

New in version 4.21